#version 450 core
layout(lines_adjacency) in;
layout(invocations = 20) in;
layout(triangle_strip, max_vertices = 4) out;
layout(std140, binding = 0) uniform TheMat { mat4 theMat; };
layout(std140, binding = 1) uniform LightsBlock {
  vec4 posBool[20];
  vec4 colRad[20];
};
vec3 lightPos = posBool[gl_InvocationID].xyz;
float theBool = posBool[gl_InvocationID].w;
float rad = colRad[gl_InvocationID].w;
vec4 shift(vec4 p) { return (vec4(p.xyz + (100000 * (p.xyz - lightPos)), 1)); };
vec4 shiftBy(float x, vec4 p) {
  return (vec4(lightPos + (x * normalize(p.xyz - lightPos)), 1));
};
vec4 shift1(vec4 p) {
  return (vec4(lightPos + (rad * normalize(p.xyz - lightPos)), 1));
};
// copied from shadow/cap.geom, should not be changed on its own
vec4 projNear(vec4 pos) {
  // note we project to a specific height
  // this is quite brittle, not ideal
  vec3 dir = pos.xyz - lightPos;
  float a = (100 - pos.z) / dir.z;
  vec2 xy = (pos.xyz + a * dir).xy;
  return vec4(xy, 100, 1);
};
vec4 shiftNear(vec4 pos) {
  vec4 sp = shift(pos);
  if (sp.z > 100) {
    return projNear(pos);
  } else {
    return sp;
  }
};
void main() {
  if (theBool == 1) {
    vec4 p0 = gl_in[0].gl_Position;
    vec4 p1 = gl_in[1].gl_Position;
    vec4 mid = 0.5 * (p0 + p1);
    vec3 n0a = gl_in[2].gl_Position.xyz;
    vec3 n1a = gl_in[3].gl_Position.xyz;
    vec3 n0 = cross(p1.xyz - p0.xyz, n0a - p0.xyz);
    vec3 n1 = cross(p0.xyz - p1.xyz, n1a - p1.xyz);
    vec3 lightDir = p0.xyz - lightPos.xyz;
    vec3 lightDir2 = p1.xyz - lightPos.xyz;
    // test if the edge is part of the silhouette
    // that is, if the normals of the faces connected by the edge point are in
    // "different directions" wrt the light direction
    if (dot(n0, lightDir) * dot(n1, lightDir) <= 0 &&
        (dot(lightDir, lightDir) < rad * rad ||
         dot(lightDir2, lightDir2) < rad * rad))
    // using <= rather than < seems to get rid of overlapping shadow
    // artefacts
    {
      vec4 p2 = shiftNear(p0);
      vec4 p3 = shiftNear(p1);
      gl_Position = theMat * p0;
      gl_Layer = gl_InvocationID;
      EmitVertex();
      if (dot(n0, lightDir) > 0) {
        gl_Position = theMat * p1;
        gl_Layer = gl_InvocationID;
        EmitVertex();
        gl_Position = theMat * p2;
        gl_Layer = gl_InvocationID;
        EmitVertex();
      } else {
        gl_Position = theMat * p2;
        gl_Layer = gl_InvocationID;
        EmitVertex();
        gl_Position = theMat * p1;
        gl_Layer = gl_InvocationID;
        EmitVertex();
      }
      gl_Position = theMat * p3;
      gl_Layer = gl_InvocationID;
      EmitVertex();
      EndPrimitive();
    } else {
    }
  } else {
  }
}