#version 450 core
struct DataS { vec2 pos; vec2 v1; vec2 v2; 
    vec2 t1r; vec2 t2r; vec2 t3r; 
    vec2 t1g; vec2 t2g; vec2 t3g; 
    vec2 t1b; vec2 t2b; vec2 t3b; 
};
layout (std430, binding = 9) readonly buffer Data { DataS data[]; };
layout (std140, binding = 0) uniform TheMat { mat4 theMat; } ;
layout (location = 0) uniform int n;
// setting n1 > 15 does not work on my current hardware
// on other hardware n = 15 might not work
// e.g. if GL_MAX_VERTEX_OUTPUT_COMPONENTS < 128
// note the vec2s might be treated as vec4s
// note also the limit on GL_MAX_VARYING_COMPONENTS
const int n1 = 15;
out vec2 texPos;
out vec2 distmask[n1];
out vec2 pinchr[n1];
out vec2 pinchg[n1];
out vec2 pinchb[n1];
const int ks[6] =   
    {0,1,2          //  2--3
    ,2,1,3          //  |  |
    };              //  0--1
const vec2 cs[4] =
    { vec2 (-1,-1)
    , vec2 ( 1,-1)
    , vec2 (-1, 1)
    , vec2 ( 1, 1)
    };
vec2 f (vec2 p) // transforms a vector from "world" into "screen" space
{ return (theMat * vec4(p,0,1) - theMat * vec4(0,0,0,1)).xy; }
vec2 ncToTex (vec2 p) {return 0.5 * (p + 1);}
// don't need mat4 here, could get away with mat3...
mat4 toTransMat (vec2 p)
{ return mat4
    (  1,  0, 0 ,0
    ,  0,  1, 0 ,0
    ,  0,  0, 1 ,0
    ,p.x,p.y, 0 ,1
    ) ;
}
void main()
{
  int k = ks[gl_VertexID];
  for(int i = 0; i < n; ++i)
  {
    DataS thedata = data[i + gl_VertexID/6];
    vec4 off = theMat * vec4(thedata.pos, 0,1);
    vec2 r1 = f(thedata.v1);
    vec2 r2 = f(thedata.v2);
    mat2 distT = inverse (mat2(r1,r2));
    distmask[i] = (distT * (cs[k] - off.xy));
    vec4 pinchxr = theMat 
        * toTransMat(thedata.t3r) 
        * toTransMat(thedata.pos)
        * mat4
          (thedata.t1r , 0, 0
          ,thedata.t2r , 0, 0
          , 0,      0 , 0, 0
          , 0,      0 , 0, 1
          )
        * inverse(toTransMat(thedata.pos))
        * inverse(theMat) 
        * (vec4(cs[k],0,1));
    pinchr[i] = ncToTex(pinchxr.xy) - ncToTex(cs[k]);
    vec4 pinchxg = theMat 
        * toTransMat(thedata.t3g) 
        * toTransMat(thedata.pos)
        * mat4
          (thedata.t1g , 0, 0
          ,thedata.t2g , 0, 0
          , 0,      0 , 0, 0
          , 0,      0 , 0, 1
          )
        * inverse(toTransMat(thedata.pos))
        * inverse(theMat) 
        * (vec4(cs[k],0,1));
    pinchg[i] = ncToTex(pinchxg.xy) - ncToTex(cs[k]);
    vec4 pinchxb = theMat 
        * toTransMat(thedata.t3b) 
        * toTransMat(thedata.pos)
        * mat4
          (thedata.t1b , 0, 0
          ,thedata.t2b , 0, 0
          , 0,      0 , 0, 0
          , 0,      0 , 0, 1
          )
        * inverse(toTransMat(thedata.pos))
        * inverse(theMat) 
        * (vec4(cs[k],0,1));
    pinchb[i] = ncToTex(pinchxb.xy) - ncToTex(cs[k]);
  }
  texPos = ncToTex(cs[k]);
  gl_Position = vec4 (cs[k],0,1);
}