#version 430 core
layout (lines_adjacency) in;
layout (triangle_strip, max_vertices = 4) out;
layout (std140, binding = 0) uniform TheMat { mat4 theMat; } ;
uniform vec3 lightPos;
vec4 shift (vec4 p) { return (vec4 (p.xyz + (1000*(p.xyz-lightPos)), 1));}
vec4 f (vec4 p) {return (theMat * p);}
void main()
{
    vec4 p0 = gl_in[0].gl_Position;
    vec3 n0 = gl_in[2].gl_Position.xyz;
    vec3 n1 = gl_in[3].gl_Position.xyz;
    //vec3 n2 = n0 + n1; // assumes the summands are normalized
    vec3 lightDir = p0.xyz - lightPos.xyz;
    // first test if the edge is part of the silhouette
    // that is, if the normals of the faces connected by the edge point in
    // "different directions" wrt the light direction
    if ( dot(n0 , lightDir) * dot(n1 , lightDir) < 0 )
    {
        vec4 p1 = gl_in[1].gl_Position;
        vec4 p2 = shift(p0);
        vec4 p3 = shift(p1);
        if ( dot(n0 , lightDir) > 0)
        {
            gl_Position = f(p0); EmitVertex();
            gl_Position = f(p1); EmitVertex();
            gl_Position = f(p2); EmitVertex();
            gl_Position = f(p3); EmitVertex();
        }
        else
        {
            gl_Position = f(p1); EmitVertex();
            gl_Position = f(p0); EmitVertex();
            gl_Position = f(p3); EmitVertex();
            gl_Position = f(p2); EmitVertex();
        }
        EndPrimitive();
    }
    else { }
}